########################################################################
# your selections:
#
# where the current sounds live
	dir_orig$ = "L:\PraatScripts\Local_time_reversal\audio"

# in ms
	windowsize = 30

# move to zero crossings
	moveToZero = 1

# name your new subfolder
	subfolder_name$ = "rev_30x"

# new filename suffix
	suffix$ = "_rev"


save_files = 1

cleanup_objects = 1
########################################################################

# make a folder for the new sounds
	if save_files == 1
	   system mkdir "'dir_orig$'/'subfolder_name$'"
	endif
# convert some numbers for clean naming
	windowsizeSEC = windowsize / 1000

# list the current sounds
	Create Strings as file list: "fileList", "'dir_orig$'\*.wav"
	num_files = Get number of strings

# loop through sounds
for file_index from 1 to num_files
	select Strings fileList
	filename$ = Get string: file_index
	Read from file: "'dir_orig$'\'filename$'"
	name$ = selected$("Sound")

	Copy... temp
	startTime = Get start time
	endTime = Get end time

	start = 0
	select Sound temp
	Edit
		editor Sound temp
		Select... start (start+windowsizeSEC)
		while start < endTime
		   call localReverse
		endwhile
		Close
	endeditor
	Rename... 'name$''suffix$'

	if save_files == 1
		Save as WAV file: "'dir_orig$'\'subfolder_name$'\'name$''suffix$'.wav"
	endif

	if cleanup_objects == 1
		select Sound 'name$'
		plus Sound 'name$''suffix$'
		Remove
	endif

endfor



########################################################################


procedure localReverse
	Select... start (start+windowsizeSEC)
	if moveToZero == 1
		Move start of selection to nearest zero crossing
		Move end of selection to nearest zero crossing
	endif
	Reverse selection
	start = start+windowsizeSEC
endproc